# Maintainer: aeris <aeris+arch@imirhil.fr>
pkgname=ekeyd
pkgver=1.1.4
pkgrel=1
pkgdesc="Daemon and CLI to manager Symtec Entropy Key"
arch=('x86_64')
url="http://www.entropykey.co.uk/"
license=('custom')
depends=(systemd lua51-socket>=20171223)
install="${pkgname}.install"
source=(
	"http://www.entropykey.co.uk/res/download/ekeyd-1.1.4.tar.gz"
	"${pkgname}-${pkgver}.patch"
)
sha256sums=(
	"147ca4ff964ab7b344a08d3cd6f9b1bf03ba18776a1941d603681d8102cce0c8"
	"SKIP"
)

prepare() {
	cd "${pkgname}-${pkgver}"
	patch -p2 -i "${srcdir}/${pkgname}-${pkgver}.patch"
}

build() {
	cd "${pkgname}-${pkgver}"
	make
}

package() {
	cd "${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}/" install
	rm -r "${pkgdir}/etc/munin" "${pkgdir}/usr/share/munin"
	install -Dm0644 "COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -Dm0644 "udev/debian/60-UDEKEY01.rules" -t "${pkgdir}/usr/lib/udev/rules.d/"
	install -Dm0744 "udev/entropykey.sh" -t "${pkgdir}/usr/lib/udev/"
	install -Dm0644 "${startdir}/${pkgname}.service" -t "${pkgdir}/usr/lib/systemd/system"
}